<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
		xmlns:_xsl="http://lichteblau.com/_xsl"
		xmlns:x="http://lichteblau.com/macro"
		version="1.0">
  <xsl:output method="xml" indent="no"/>

  <xsl:namespace-alias stylesheet-prefix="_xsl" result-prefix="xsl"/>

  <xsl:template match="xsl:stylesheet">
    <xsl:copy>
      <!-- copy the stylesheet -->
      <xsl:apply-templates select="@*|node()"/>
      <!--
	  but add an extra template for each use of the `dotimes'
	  macro, which implement the iteration using recursion
	-->
      <xsl:for-each select="//x:dotimes">
	<_xsl:template name="x:dotimes_{generate-id()}">
	  <_xsl:param name="x:count"/>
	  <_xsl:param name="{@var}"/>
	  <_xsl:if test="${@var} &lt; $x:count">
	    <xsl:apply-templates/>
	    <_xsl:call-template name="x:dotimes_{generate-id()}">
	      <_xsl:with-param name="x:count" select="$x:count"/>
	      <_xsl:with-param name="{@var}" select="${@var} + 1"/>
	    </_xsl:call-template>
	  </_xsl:if>
	</_xsl:template>
      </xsl:for-each>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <!-- use like this: <x:dotimes var="i" count="10">...</x:dotimes> -->
  <xsl:template match="x:dotimes">
    <_xsl:call-template name="x:dotimes_{generate-id()}">
      <_xsl:with-param name="x:count" select="{@count}"/>
      <_xsl:with-param name="{@var}" select="0"/>
    </_xsl:call-template>
  </xsl:template>

  <!-- use like this: <x:br/> -->
  <xsl:template match="x:br">
    <_xsl:text><xsl:text>&#10;</xsl:text></_xsl:text>
  </xsl:template>
</xsl:stylesheet>